Recup de var _global

Bonjour,

Voila j'ai un petit probleme que je n'arrive pas a resoudre !

J'ai d'un coté des boutons dupliqués suivant le nombres d'image de ma galerie !
De l'autre coté, j'ai un mcImage qui ce charge de loader l'image !

Maintenant pour chaqu'un des boutons respectifs, je voudrai crée une variable qui contient le chemin de l'image !
Apres je voudrai, recuperer cette variable dans le mcImage "qui charge l'image"!

J'ai fais déjà l'action sur les boutons dupliquer :

btn.onRelease = function()
{
_global.adresse = new String(url);
......

J'essaye de la traceer sur le mcImage avec :

onEnterFrame = function ()
{
    trace(adresse);
}

Mais quand je trace dans mcImage il me le sort en boucle trop bizar ! C'est la boucle du onEnterFrame qui me fais ca je crois ! Comment faire pour le tracer une seulement fois ?

Désolé pour l'explique mais il faut que je vous donne plein d'info pour que vous comprenier !

Merci

Salut !

C'est normal ! OnEnterFrame est appelé continuellement !

Il faut que tu fasses :

onEnterFrame = function ()
{
    trace(adresse);
    delete this.onEnterFrame; // supprim la fonction, pour l'appeler une seule fois
}

a+++

Bonjour,

Si je mais, delete this.onEnterFrame; je ne peux plus envoyé la variable par la suite !
Pourquoi ????

Parceque ta fonction onEnterFrame n'existe plus !

Ce qu'il faudrait faire, c'est créer une fonction que t'apelle quand t'as besoin !

ex ;

btn.onRelease = function()
{
_global.adresse = new String(url);
_root.maFonction();
....

et sur _root :

function maFonction()
{
   trace(adresse);
}

ou quelquechose dans le genre, en fonction de ce que tu veux faire !

J'ai essayé, mais ca fonctionne pas ! Je vais faire ca directement depuis le bouton c'est plus simple !

Merci encors !

ouep a mon avis, c'est le plus simple ! ;)

Lol...faut faire le test avant de faire delete onEnterFrame...là tu le crées et tu le supprimes tout de suite...ajoute:

onEnterFrame = function () 

   if(adresse!=""){
      trace(adresse);    
      delete this.onEnterFrame;
   }
}

Ca devrait t'afficher la valeur une seule fois dès que tu la transmets.

@+! Samy

ouep mé a mon avis, il faut que le trace(adresse); se fasse a chaque release de bouton !
en faisant ca, ca marchera que lors du premier appui ! non ?

Mouais...ben à mon avis le trace c'est pour faire le test et voir si ça passe bien au clip mcImage...donc si ça marche avec 1 bouton...il relance l'anim essaie avec un 2ème...et puis basta il supprimera le onEnterFrame!

De toute façon, doit y avoir une gestion par XML (j'espère! lol) donc il aura un attribut adresse (j'espère! lol) et puis y'aura même pas besoin de _global.adresse, puisqu'il pourra y accéder avec l'arborescence de l'objet XML.

Voilà...au fait...j'avais pas lu vos 3 posts (j'étais parti entre temps) et créer une fonction c'est pas mal.

Autre solution: crée les actions associées au bouton lors de sa création (vu qu'il devrait y avoir une boucle "FOR" ...si c'est vraiment dynamique!). =>solution valable si y'a pas trop d'actions à faire, sinon bien sûr que c'est mieux de prendre une fonction!

@+! Samy

Toute à fais il y a une gestion par XML est je veux belle est bien tester si ca passe ! Si quelqu'un a une solution plus claire a me proposer je suis preneur ! ;)

Je vous balance le script si vous voulez voir !

//Recuperation du contenu XML
System.useCodepage = true;
donnees_XML = new XML();
donnees_XML.ignoreWhite = true;
donnees_XML.load('galerie_travaux.xml');
donnees_XML.onLoad = function(ok)
{
    if(ok)
    {
        var noeudstravaux = this.firstChild.childNodes;
        var n = noeudstravaux.length;
        //Je crée la boucle qui va dupliquer le bouton suivant le nombre d'image
        for (var a=0;a<n;a++)
        {
            //Je duplique le mc_btnTravaux
            var btn = mc_zoneBtn.attachMovie("mc_btnTravaux","btnNumero"+a,1 + a);
            btn.numero = noeudstravaux[a].attributes.num;

            //Lancement de la fonction Action qui alimente le divers action ci-dessous
            var Action = function (btn, url, titre, texte, date, numero, total)
            {
                //Si aucun bouton presser on affiche le dernier enregistrement auto
                fenetre.chargementImage.adresse = new String(url);
                fenetre.affTitre.text = titre;
                mc_texte.texte.text = texte;
                mc_texte.date.text = date;
                fenetre.numero.text = numero + " /";
                fenetre.total.text = total;
               
                //Si bouton presser on affiche l'image selectionner
                btn.onRelease = function()
                {
                    fenetre.chargementImage.adresse = new String(url);
                    fenetre.affTitre.text = titre;
                    mc_texte.texte.text = texte;
                    mc_texte.date.text = date;
                    fenetre.numero.text = numero + " /";
                    fenetre.total.text = total;
                    btn._alpha = 70;
                }
               

                fenetre.onRelease = function()
                {
                    getURL(url, "_blank", "POST");
                }
                //Si survol de la fenetre on affiche le bouton click
                fenetre.onRollOver = function()
                {
                    this.btn_click.gotoAndPlay(2);
                }
                //Si ne survol pas de la fenetre on fais disparaitre le bouton click
                fenetre.onRollOut = function()
                {
                    this.btn_click.gotoAndPlay(9);
                }
                //Si survol du bouton on affiche lance les animation divers
                btn.onRollOver = function()
                {
                    this.gotoAndPlay(2);
                    startDrag("info", true);
                    info._alpha = 100;
                    info.nom._visible = true;
                    info.nom.text = titre;
                }
                //Si ne survol pas le bouton on fais disparaitre les animation divers
                btn.onRollOut = function()
                {
                    this.gotoAndPlay(11);
                    startDrag("info", false);
                    info._alpha = 0;
                    info.nom._visible = false;
                }
            }
            // Les divers action juste ci-dessus
            Action(
                      btn,
                      noeudstravaux[a].attributes.url,
                      noeudstravaux[a].attributes.titre,
                      noeudstravaux[a].attributes.texte,
                      noeudstravaux[a].attributes.date,
                      noeudstravaux[a].attributes.num,
                      n
                      );
           
            // Definition du nombre de colonne suivant prototype en dessous
            btn.colonne(a, "Horizontal", 1, 20, 0);
        }
    }
}
//Fonction prototype du nombre de colonne(s)
MovieClip.prototype.colonne = function(a, sSens, aNbRangee, aDecalageX, aDecalageY)
{
    if (sSens == "Horizontal")
    {
        this._x = aDecalageY * ( a % aNbRangee );
        this._y = aDecalageX * Math.floor( a / aNbRangee );
    }
};
stop();