points clefs dans FLV en AS2

Réponse acceptée !
là, j'ai une video qui en déclenche deux autres au passage des cuePoints, si ça peut t'aider, volà mon code :
import mx.video.*;

var videoScreen1:MovieClip;
var videoScreen2:MovieClip;
var nc:NetConnection = new NetConnection();
nc.connect(null);

var ns1:NetStream = new NetStream(nc);
var ns2:NetStream = new NetStream(nc);
videoScreen1.ourVideo.attachVideo(ns1);
videoScreen2.ourVideo.attachVideo(ns2);

var ourListener:Object = new Object();
ourListener.cuePoint = function( eventObject:Object ):Void {
    var cuePointName = eventObject.info.name;
    if( cuePointName == "trailer1" ) {
        ns1.play( cuePointName + ".flv" );
    } else if( cuePointName == "trailer2" ) {
        ns2.play( cuePointName + ".flv" );
    }
}

// on ajoute nos "cue points"
videoComp.addASCuePoint( 8.594, "trailer1" );
videoComp.addASCuePoint( 18.354, "trailer2" );

videoComp.addEventListener( "cuePoint", ourListener );
stop();

mon lecteur principal est le composant FLVPlayback, nommé ici "videoComp" et les 2 autres vidéo sont "trailer1" et "trailer2", voilà le principe avec un écouteur.

Alise
from FlashForum-oi.info

Réponse acceptée !
seekToNavCuePoint fonctionne avec des repères incorporés à la video.flv, si tu n'as pas ces repères ton code ne fonctionnera pas.

Quant à l'import de la class "mx.video.*;", elle n'est pas utile, mais c'est une habitude de travail, quand on travaille avec des classes, celle-ci est incluse dans flash.

Tu peux très bien adapter le code que je t'ai passé à ton prob, c'est simplement un point de départ, utilisation d'un objetListener et d'un listener, classique en AS2

Alise
from FlashForum-oi.info

Réponse acceptée !
tu as dans l'aide flash ceci qui peut aussi t'aider ;

Dans les exemples suivants, vous ajoutez un bouton que vous utilisez pour alterner entre les points de repère ou une durée spécifiée dans un fichier FLV qui est lu dans le composant FLVPlayback, et un bouton pour atteindre un point de repère spécifié.

Pour rechercher à une durée spécifiée :

Créez un document Flash appelé seekduration.fla.
Faites glisser une occurrence du composant FLVPlayback du panneau Composants (Fenêtre > Composants).
Le composant est dans le dossier FLVPlayback - Player 8.

Choisissez le composant et ouvrez l'inspecteur des propriétés (Fenêtre > Propriétés > Propriétés).
Tapez my_flvPb dans le champ Nom de l'occurrence.
Faites glisser une occurrence du composant Button du panneau Composants sur la scène.
Choisissez le composant Button et tapez seek_button dans le champ Nom de l'occurrence.
Sélectionnez l'image 1 du scénario, puis tapez le code suivant dans le panneau Actions :
import mx.controls.Button;
import mx.video.FLVPlayback;
var seek_button:Button;
var my_flvPb:FLVPlayback;
my_flvPb.autoPlay = false;
my_flvPb.contentPath = "http://www.helpexamples.com/flash/video/sheep.flv";
seek_button.label = "Seek";
seek_button.addEventListener("click", seekFlv);
function seekFlv(eventObj:Object):Void {
    // Recherche à 2 secondes
    my_flvPb.seek(2);
}
Choisissez Contrôle > Tester l'animation pour tester votre code.
Lorsque vous cliquez sur le bouton, la tête de lecture vidéo se déplace jusqu'à la durée spécifiée : 2 secondes dans la vidéo.

Alise
from FlashForum-oi.info

Réponse acceptée !
Salur Alise !

ça y'est tout marche nickel gràçe au fameux seekToNavCuePoint('blablabla')

J'ai réencodé la vidéo en insérant les points clefs à ce moments là.
j'ai nommé chaque point clefs cue_0, cue_1, cue_2 ... etc

ensuite j'ai sur ma scène 11 boutons (cuePoint_0 à cuePoint_10)

Chaqu'un reçoit la fonction ci-dessous :

function btCP(cp){
    //
    cp.onRollOver = function(){
        this.gotoAndStop('over');
    }
    cp.onRollOut = cp.onReleaseOutside = function(){
        this.gotoAndStop('out');
    }
    ////////////////////////////// LA PARTIE QUI NOUS INTERESSE // //////////////// //////////////// ////////////
    cp.onRelease = function(){
        // video_mc est un clip qui contient mon composant ( flvPBK_mc).
        // il faut juste recomposer le nom du cuePoint intégré dans le flv en utilisant l'id du bouton :
        video_mc.flvPBK_mc.seekToNavCuePoint( 'cue_' + cp._name.substr(9, 2) );
        video_mc.flvPBK_mc.stop();
    }
    ///////////////////////// //////////////// //////////////// //////////////// //////////////// //////////////// ////////////////
};

// -------------------------------------------------------------- //
// c'est là qu'on donne active les boutons :
for (var i:Number=0; i<nbreCuePoints; i++){
    btCP( eval('cuePoint_' + i) );
};


Bref problème enfin résolu et joie immense

Merci à toi pour ce partage d'infos et bonne continuation
Sep