Menu style dock

Bonjour à tous,

J'ai récupéré une source pour faire un menu style dock mac. Voici le code :

align = bottom;
centerx = 132;
centery = 107;
menuholder = createEmptyMovieClip("menuholder", -1);
menuholder._y = centery;
menucount = 7;
menuitems = [];
miwidth = 37;
miborder = 1;
startx = centerx-((menucount-1)*(miwidth+miborder))/2;
trace(startx);
for (var i = 0; i<menucount; i++) {
    var menuitem = menuholder.attachMovie("menuitem", "menu"+i, i);
    menuitem._x = startx+i*(miwidth+miborder);
    menuitem.id = i;
    menuitem.onRollOver = function() {
        _root.selected = this;
    };
    menuitems.push(menuitem);
}
onEnterFrame = function () {
    var width = 0;
    for (var i = 0; i<menucount; i++) {
        var xxm = menuitems[i]._xmouse;
        var yym = menuitems[i]._ymouse;
        var xm = Math.sqrt(xxm*xxm+yym*yym);
        if (xm<50) {
            menuitems[i]._xscale = menuitems[i]._yscale += ((200-xm)-menuitems[i]._yscale)/3;
        } else {
            menuitems[i]._xscale = menuitems[i]._yscale += (100-menuitems[i]._yscale)/3;
        }
        width += menuitems[i]._width;
    }
    width += (menucount-1)*miborder;
    var xpos = Math.round(centerx-width/2);
    for (var i = 0; i<menucount; i++) {
        for (var i = 0; i<menucount; i++) {
            if (i>0) {
                xpos += menuitems[i-1]._width/2;
            }
            xpos += miborder+menuitems[i]._width/2;
            menuitems[i]._x = xpos;
        }
    }
};


Je souhaiterais faire en sorte que sur les mc (menuitem) générés apparaisse des images (une pour chaque menuitem), éventuellement appelé par xml ou autre.  Comment puis-je faire cela?

D'avance merci pour votre aide

Hello,

Ca ce joue au niveau de la ligne suivante :
var menuitem = menuholder.attachMovie("menuitem", "menu"+i, i);

soit tu as plusieurs movieclip ("menuitem0", "menuitem1",...) dans ta bibliotheque avec les différentes images déjà dedans.

for (var i = 0; i<menucount; i++) {
    var menuitem = menuholder.attachMovie("menuitem"+i, "menu"+i, i);
   ...
}

ou bien tu crée un movieclip vide et tu charges une image dedans

for (var i = 0; i<menucount; i++) {
    var menuitem = menuholder.createEmptyMovieClip("menuitem"+i,  i);
    menuitem.loadMovie("images/menuimage"+i+".jpg")
   ...
}
@+

Super, merci Girou, je teste tout ça!

J'ai encore un petit problème. Je souhaiterais maintenant associer à chacun de mes menuitem une action bouton pour aller vers une image d'un clip sur la scène avec le nom d'occurence "contenu". J'ai essayé avec : menuitem.onPress = function() { contenu.gotoAndStop(i+1); }; après menuitem.onRollOver = function() { _root.selected = this; }; mais ça ne marche pas...

J'ai encore un petit problème. Je souhaiterais maintenant associer à chacun de mes menuitem une action bouton pour aller vers une image d'un clip sur la scène avec le nom d'occurence "contenu".

J'ai essayé avec :

        menuitem.onPress = function() {
        contenu.gotoAndStop(i+1);

    };

après


    menuitem.onRollOver = function() {
        _root.selected = this;
    };

mais ça ne marche pas...

Salut,

chaque menuitem recoit un id via la ligne de code :
menuitem.id = i;

c'est cette variable que tu dois utiliser

menuitem.onPress = function() {
        this._parent.contenu.gotoAndStop(this.id+1);
        // ou encore _root.contenu.gotoAndStop(this.id+1);
    };

@+

Merci Girou! Toujours au rendez-vous! C'est sympa

Alors, j'ai essayé comme cela, mais ça ne fonctionne pas. Est-ce que c'est parce qu'on attribue une fonction bouton au clip? Une idée d'où pourrait venir le problème! Merci d'avance!

Effectivement, si tu utlise la technique du loadMovie alors cela ne va pas marcher... loadMovie va ecraser les fonction définie sur le clip une fois l'image chargée.

Pour remédier a cela, tu crée ton clip et tu charge l'image dans un second clip créer dans le premier
en plus concret, cela donne :

for (var i = 0; i<menucount; i++) {
    var menuitem = menuholder.createEmptyMovieClip("menuitem"+i,  i);
    var imgContainer=menuitem .createEmptyMovieClip("img",  1);
    imgContainer.loadMovie("images/menuimage"+i+".jpg")
    menuitem._x = startx+i*(miwidth+miborder);
    menuitem.id = i;
    menuitem.onRollOver = function() {
        _root.selected = this;
    };
    menuitem.onPress = function() {
        this._parent.contenu.gotoAndStop(this.id+1);
        // ou encore _root.contenu.gotoAndStop(this.id+1);
    };
    menuitems.push(menuitem);
}

@+

Merci mille fois pour ton aide