je veux que mon lecteur mp3 soit en streaming

bonjour, voila, j'ai placé un petit lecteur mp3 sur mon site qui appelle les mp3 en loadmovie , le problème est que la chanson ne démarre que quand elle est chargée entièrement, ce qui prend du temps pour les petites connections, je voudrais faire en sorte qu'il soit en streaming mais sans refaire tout le lecteur, je pense qu'il n'y a qu'un code à rajouter?
merci d'avance

Salut,

si tu appelles des mp3 via un loadMovie, tu n'as aucune chance de le jouer en streaming...
par contre, regarde du coté de l'objet Sound et loadSound()

var my_sound:Sound = newSound();
my_sound.loadSound("song1.mp3", true);

le parametre true de loadSound indique que l'on souhaite jouer le mp3 en streaming...

@+

bonjour, j'ai tendance à membrouiller un peu dans les codes: voici ceux qui sont sur mon petit lecteur
premier calque :
var _pos:Number = 0;
var _current:Number = 0;
var _autoPlay:Boolean = false;

var ID3:String;
var ID3Texte:TextField;
ID3Texte.autoSize = "right";
ID3Texte.embedFonts = false;
ID3Texte._visible = false;

var music:Sound = new Sound(this);
music.onID3 = function(){
    /*for( var prop in music.id3 ){
        trace( prop + " : "+ music.id3[prop] );
    }*/
    ID3 = "<b>"+music.id3.songname+"</b> - "+music.id3.artist+" - "+music.id3.year;
    ID3Texte.htmlText = ID3;
}
music.onLoad = function(success){
    if (!success){
        showErreur("Fichier Introuvable");
    } else {
        if (_autoPlay) lecture();
    }
}
music.onSoundComplete = function(){
    _pos = 0;
    LectPause.gotoAndStop(1);
    if (_current < liste.length){
        suivant();
    } else {
        _current = 0;
        charger();
    }
}
function suivant(){
    _autoPlay = true;
    _current++;
    if (_current == liste.length) _current = 0;
    charger();
}
function precedent(){
    _autoPlay = true;
    _current--;
    if (_current < 0) _current = liste.length-1;
    charger();
}

function charger(){
    _pos = 0;
    music.loadSound(liste[_current]);
    music.setVolume(50);
}

function lectPause(){
    if (LectPause._currentframe == 1){
        lecture();
    } else {
        pause();
    }
}
function lecture(){
    LectPause.gotoAndStop(2);
    music.start(_pos);
}
function pause(){
    LectPause.gotoAndStop(1);
    _pos = music.position/1000;
    music.stop();
}
function arreter(){
    LectPause.gotoAndStop(1);
    music.stop();
    _pos = 0;
}
function showID3Temp(){
    showID3();
    id3Interval = setInterval(hideID3,3000);
}
function showID3(){
    ID3Texte._visible = true;
}
function hideID3(){
    ID3Texte._visible = false;
    if (id3Interval) clearInterval(id3Interval);
}

LectPause.gotoAndStop(1);
LectPause.onRelease = lectPause;
LectPause.onRollOver = showID3;
LectPause.onRollOut = hideID3;
Arreter.onRelease = arreter;
Arreter.onRollOver = showID3;
Arreter.onRollOut = hideID3;
Fond.useHandCursor = false;
Fond.onRollOver = showID3;
Fond.onRollOut = hideID3;
Precedent.onRelease = precedent;
Precedent.onRollOver = showID3;
Precedent.onRollOut = hideID3;
Suivant.onRelease = suivant;
Suivant.onRollOver = showID3;
Suivant.onRollOut = hideID3;

charger();



sur le 2e   :
function show(){
    _visible = true;
}

function hide(){
    _visible = false;
}
show();


sur le 3e:
var liste:Array = new Array();
liste.push("mp3/Lofofora_Subliminable.mp3");
liste.push("mp3/Billy Talent_Try Honesty.mp3");
liste.push("mp3/Incubus_New Skin.mp3");
liste.push("mp3/Lostprophets_Start Something.mp3");


sur lequel je dois mettre mes loadsound
merci d'avance!!!!!

Bonjour,

voici l'endroit dans le code

function charger(){
    _pos = 0;
    music.loadSound(liste[_current],true);
    music.setVolume(50);
}

Par contre, il est fort probable que cela rentre ne conflit avec la fonction music.Onload

De toute façon, ce n'est pas parce que c'est du streaming que la musique va commencer tout de suite, le lecteur va d'abord mettre assez de données en mémoires pour pouvoir jouer la musique sans devoir l'interrompre a cause du chargement de la suite. Donc, plus la connexion est lente, plus le lecteur va devoir attendre et mettre des données en mémoire.

Et décidément, je vois pas ou tu charges tes mp3 en loadLovie dans ce code...

@+

oui excuse moi je métais mal expliké, ct pas en load movie, je vais essayer ta méthode et je te tiens au courant si ça fonctionne.
+++

salut, voila j'ai changé le code au bon endroit, et quand j'exporte en swf, ça marche nikel, par contre quand je met mon site sur le web , ça bug  (jespère que c'est dû à ma connection de merde) mais ya rien qui se lance
est-ce que c'est possible de rajouter un petit code pour qu'il y ait une sorte de preload avant les chansons?
merci d'avance!!!!