[AIR] ENREGISTRER LOCALEMENT UNE IMAGE CRÉÉE DYNAMIQUEMENT

import PNGEncoder;

/**** AFFICHAGE DE L'IMAGE PAR BLACKNIGHT : (cf source précédene) ****/

var myPicture:BitmapData=new BitmapData(100,100,true,0x00000000);

for (var i:int=0; i<100; i++) {
	myPicture.fillRect(new Rectangle(100*Math.random(),100*Math.random(),10*Math.random(),10*Math.random()),0xFFFFFFFF*Math.random());
}

var image:Bitmap = new Bitmap(myPicture);

addChild(image);

image.x = 70;
image.y = 15;


/**** VARIABLES ****/



// dossier de l'application dans les dossiers "système"
var dossier:File = File.applicationStorageDirectory;

/******************* /!\ /!\ /!\ /!\/!\ ********************

File.applicationStorageDirectory renvoit au dossier de "configuration" de l'application.

Ce dossier est situé dans AppData/Roaming/com.adobe.example.VOTREPROJET pour Vista
et dans Bibliothèque > Préférences > com.adobe.example.VOTREPROJET Pour les macs



Pour enregistrer dans le dossier de l'application, il faut utiliser >>> File.applicationDirectory <<<

Ça enregistre dans le dossier de l'application sous Windows (genre C:/Program Files/Mon App/)
et DANS le .app sous mac (dans monApp.app/Contents/Resources/)

Dans n'importe quel cas les loader fonctionnent car sous Windows c'est le exe qui charge
et pour les macs c'est le main.swf contenu dans monApp.app/Contents/Resources/ qui charge.

***********************************************************/

// image finale dans l'ordi
var imageEnregistree:File = dossier.resolvePath("enregistrees/image.png");


// les variables de dossiers ont été changées suite au commentaire de Pegase. Déjà c'est plus simple, plus explicite, et en plus, on pourra faire des tests plus tard sur ce chemin ciblé


/****** ENREGISTREMENT *******/

function enregistrerFct (evt:Event) {
	
	// On encode en PNG
	var monPNGByte:ByteArray = PNGEncoder.encode(myPicture);
	
	// on ouvre le filestream pour écrire (en l'occurence) sur l'ordi
	var stream:FileStream = new FileStream();
	
	// on ECRIT sur l'emplacement de l'image défini plus haut
	stream.open(imageEnregistree, FileMode.WRITE);
	
	// on écrit quoi ? Le bytearray bien sûr :)
	stream.writeBytes(monPNGByte);
	
	// Et on ferme la porte pour éviter les courants d'air
	stream.close();
	
	confEnregistrement.text = "Enregistrée sous "+imageEnregistree.url;
	
}
enregistrer.addEventListener(MouseEvent.CLICK, enregistrerFct);


/***** REAFFICHAGE ******/

// Là, rien de bien sorcier... Le loader fonctionne...

function afficherFct (evt:Event) {
	
	if(imageEnregistree.exists) {
		
		var chargeur:Loader = new Loader();
		chargeur.load(new URLRequest(imageEnregistree.url));
		
		addChild(chargeur);
		
		chargeur.x = 86;
		chargeur.y = 270;
		
	}
	
}

charger.addEventListener(MouseEvent.CLICK, afficherFct);